ffmpeg-gui/build.bat

@echo off
chcp 65001 >nul
echo === FFmpeg GUI Build Script ===
echo.

cd /d "%~dp0"

echo [1/3] Installing frontend dependencies...
cd frontend
call npm install
if %errorlevel% neq 0 (
    echo ERROR: npm install failed
    pause
    exit /b %errorlevel%
)

echo [2/3] Building frontend...
call npm run build
if %errorlevel% neq 0 (
    echo ERROR: frontend build failed
    pause
    exit /b %errorlevel%
)
cd ..

echo [3/4] Checking ffmpeg binaries for bundling...
if exist "bundled\ffmpeg.zip" (
    echo   bundled\ffmpeg.zip found, will be embedded
) else (
    echo   WARNING: bundled\ffmpeg.zip NOT found
    echo   Zip ffmpeg.exe + ffprobe.exe into bundled\ffmpeg.zip to bundle.
    echo   The app will fall back to system PATH if ffmpeg is installed.
)

echo [4/4] Cleaning icon cache...
if exist "build\windows\icon.ico" del /q "build\windows\icon.ico"
if exist "*-res.syso" del /q "*-res.syso"

echo [5/5] Building Wails application...
wails build -clean -platform windows/amd64
if %errorlevel% neq 0 (
    echo ERROR: wails build failed
    pause
    exit /b %errorlevel%
)

echo.
echo === Build complete! ===
echo Output: bundled\ffmpeg-gui.exe
echo.